/*
 * Oblivion 
 * by Paolo Tonon. 
 */

int w = 780;
int h = 532;
int numberBox = 12;

//

int maxX =int(w/numberBox);
int maxY =int(h/numberBox);
int largeur;
float camX,camY,camZ;
Cube[][] cubes = new Cube[maxX][maxY];
float spaceX = w/maxX;
float spaceY = h/maxY;

//

int puntoX = 1;
int puntoY = 1;
boolean versoX = true;
boolean versoY = true;


/*
 * Background Subtraction 
 * by Golan Levin. 
 */

import processing.video.*;

int numPixels;
int[] backgroundPixels;
int[] storedPixels;
Capture video;


static public void main(String args[]) {
  PApplet.main(new String[] { "--present", "oblivion" });
}


void setup(){
  size(w,h,P3D);
  colorMode(RGB,255);
  frameRate(20);
  largeur= width/maxX-(width/maxX)/maxX;
  camZ=(height/2.0) / tan(PI*60.0 / 360.0);
  for (int i = 0; i <maxX;i++){
    for (int j = 0; j <maxY;j++){
      cubes[i][j]=new Cube(i*largeur,j*largeur,largeur);
    }
  }
  video = new Capture(this, width, height, 25);
  numPixels = video.width * video.height;
  // Create array to store the background image
  backgroundPixels = new int[numPixels];
  storedPixels = new int[numPixels];
}

void draw(){
  if (versoX==true){
    puntoX++;
    if (puntoX == width){
      versoX=false;
    }
  } 
  else {
    puntoX--;
    if (puntoX == 1){
      versoX=true;
    }
  }
  if (versoY==true){
    puntoY++;
    if (puntoY == width){
      versoY=false;
    }
  } 
  else {
    puntoY--;
    if (puntoY == 1){
      versoY=true;
    }
  }
  camera(map(puntoX,0,width,width/3,width*2/3),map(puntoY,0,height,height/3,height*2/3), camZ,width/2.0, height/2.0,0, 0, 1, 0);
  background(0);
  lights();
  if (video.available()) {
    video.read(); // Read a new video frame
    video.loadPixels(); // Make the pixels of video available
    // Difference between the current frame and the stored background
    int presenceSum = 0;
    for (int i = 0; i < numPixels; i++) { // For each pixel in the video frame...
      // Fetch the current color in that location, and also the color
      // of the background in that spot
      color currColor = video.pixels[i];
      color bkgdColor = backgroundPixels[i];
      // Extract the red, green, and blue components of the current pixel’s color
      int currR = (currColor >> 16) & 0xFF;
      int currG = (currColor >> 8) & 0xFF;
      int currB = currColor & 0xFF;
      // Extract the red, green, and blue components of the background pixel’s color
      int bkgdR = (bkgdColor >> 16) & 0xFF;
      int bkgdG = (bkgdColor >> 8) & 0xFF;
      int bkgdB = bkgdColor & 0xFF;
      // Compute the difference of the red, green, and blue values
      int diffR = abs(currR - bkgdR);
      int diffG = abs(currG - bkgdG);
      int diffB = abs(currB - bkgdB);
      // Add these differences to the running tally
      presenceSum += diffR + diffG + diffB;
      // Render the difference image to the screen
      storedPixels[i] = 0xFF000000 | (diffR << 16) | (diffG << 8) | diffB;
    }
    //updatePixels(); // Notify that the pixels[] array has changed
    //println(presenceSum); // Print out the total amount of movement
    translate(largeur,largeur,-100);
    for (int i = 0; i <maxX;i++){
      for (int j = 0; j <maxY;j++){
        // w- : flip the image
        int pixelSpace = int((w-(i*spaceX))+((w*j)*spaceY));
        //println(pixelSpace);
        cubes[i][j].move(storedPixels[pixelSpace],video.pixels[pixelSpace]);      
      }
    }
  }
}


void mouseDragged(){
  camera(map(mouseX,0,width,width/3,width*2/3),
  map(mouseY,0,height,height/3,height*2/3), camZ,width/2.0, height/2.0,
  0, 0, 1, 0);
}

void mousePressed() { 
  video.loadPixels();
  // set the background;
  arraycopy(video.pixels, backgroundPixels);
}

void keyPressed() {
  if (key == 'i' || key == 'I') {
      float m = millis();
      save(m+".tif");
    }
} 



class Cube{
  float x,y,z,l,h,s,step,top,bottom=0;
  Cube(float x, float y, float l){
    this.x=x; 
    this.y=y; 
    this.l=l;
    top=150;
    step=2;
    z= bottom;
    h= 122;
    s=155;
  }

  void move(color cubeColor, color videoColor){
    pushMatrix(); 
    translate(x,y,z); 
    fill(videoColor);
    box(l,l,l); 
    popMatrix();

    z+=step;
    if (z>100){
      z=100;
    } 
    else if(z<-800){
      z=-800;
    }
    color blackReference = color (40);
    if(cubeColor > blackReference){
      step=(30);
    }
    else{
      step=-(10);
    }
  }
}